Blog Developer's Cookbook : Weblogs.com Ping Gateway to はてなアンテナ (POE版)

URI.pm を使用して、はてなアンテナの更新通知用の URL を生成します(*9)。HTTP::Request オブジェクトを new して、Client::HTTP である ua に、リクエストを投げる依頼をします。メソッド request の引数は、リクエストに対するレスポンスを受け取った際に起動されるイベント名 (got_response)、HTTP::Request オブジェクトです。

そして前回と同様、weblogUpdates.ping の返り値である構造体を作成して $transaction 経由で return しています。実際には先ほどの $poe->kernel->post() も $transaction->return() も、イベントがキューイングされるだけで、その後 POE カーネルにより非同期で実行されることに注意してください。

こうして、はてなアンテナへのリクエスト送信とレスポンス受信を待つことなく、Blog クライアントに Ping のレスポンスを返すことができます。

実行例

ここでは単体での確認のため、XML-RPCのクライアントも自作して実行してみましょう。XMLRPC::Lite を使用したクライアントスクリプトは List 2 のような簡単なものになります。引数に XML-RPC の URL, Blog名と Blog URL を指定して実行します。

サーバのシャットダウンは Ctrl-Z でサスペンドし、 PID を指定して kill しましょう。

まとめ

Listings

List 1: ping_to_hatena_poe.pl

#!/usr/local/bin/perl -w
# ping_to_hatena_poe
# - Weblogs.Com Ping Gateway to Hatena Antenna (POE)

use strict;
use POE qw(Component::Server::XMLRPC
           Component::Client::HTTP
           Component::TSTP);
use POE::Sugar::Args;
use HTTP::Request;
use Sys::Hostname;
use URI;

our $VERSION    = "1.00";
our $HatenaURL  = "http://a.hatena.ne.jp/check";

my $port = shift || 10080;

# session to trap Ctrl-Z
POE::Component::TSTP->create();

# session for XML-RPC server
POE::Component::Server::XMLRPC->new(
    alias => 'xmlrpc',
    port  => $port,
);

# session to send pings in HTTP
POE::Component::Client::HTTP->spawn(
    Alias => 'ua',
    Agent => "ping2hatena/$VERSION",
);

# main session
POE::Session->create(
    inline_states => {
        _start => \&setup_service,
        _stop  => \&shutdown_service,
        "weblogUpdates.ping" => \&ping_handler,
        got_response => \&response_handler,
    },
);

$poe_kernel->run();

sub setup_service {
    my $poe = sweet_args;
    $poe->kernel->alias_set("ping2hatena");
    $poe->kernel->post(xmlrpc  => 'publish',
                       ping2hatena => "weblogUpdates.ping");
    my $hostname = Sys::Hostname::hostname || 'localhost';
    warn "URI: http://$hostname:$port/?session=ping2hatena\n";
}

sub shutdown_service {
    my $poe = sweet_args;
    $poe->kernel->post(xmlrpc  => 'rescind',
                       ping2hatena => "weblogUpdates.ping");
}

sub ping_handler {
    my $poe = sweet_args;
    my $transaction = $poe->args->[0];
    my($blog_name, $blog_url) = @{$transaction->params()};
    my $url = URI->new($HatenaURL);
       $url->query_form(url => $blog_url);
    my $req = HTTP::Request->new(GET => $url);
    $poe->kernel->post(ua => request => got_response => $req);

    my %data = (flerror => XMLRPC::Data->type(boolean => 0));
    $transaction->return(\%data);
}

sub response_handler {
    my $poe = sweet_args;
    my $request  = $poe->args->[0]->[0];
    my $response = $poe->args->[1]->[0];
    if (defined($response->content)) {
        warn "successful request to ", $request->uri();
    } else {
        warn "error while requesting ", $request->uri();
    }
}

List 2: ping_client.pl

#!/usr/local/bin/perl -w
# ping_client - weblogUpdates.ping client

use strict;
use XMLRPC::Lite;
my($proxy, @args) = @ARGV;

my $result = XMLRPC::Lite
    ->proxy($proxy)
    ->call("weblogUpdates.ping", @args)
    ->result;
print "flerror=$result->{flerror}\n";

*1) ソケットの読み書きやファイルロックなど、外的要因で待たされる処理
*2) というより気持ちよくない
*3) interpreter based threads を略して ithreads と呼ばれます
*4) threads::shared を使用して明示的に共有する必要があります。
*5) 詳細は What POE Is を参照してください。
*6) しばしば POE::Component:: は PoCo:: と略されることがあります
*7) 前回は my で宣言して BEGIN { } で設定していました。
*8) POE::Component::Server::XMLRPC のドキュメントには書いていない (EXAMPLE にかろうじて書いてある) のでハマりやすいです
*9) 前回は URI::Escape と sprintf を使用していました。

Weblogs.com Ping Gateway to はてなアンテナ (POE版)

Perl の非同期処理

サンプルコード

実行例

まとめ

Listings