Blog Developer's Cookbook : Trackback Ping を送信する

パラメータ	意味
url	URL
blog_name	Blog 名
title	タイトル
excerpt	概要

CPAN モジュール Net::TrackBack は、リファレンス実装をモジュール化して使いやすくしたものです。

No Host Trackback のように、Trackback に対応していない Blog ツール向けのホスティングサービスも用意されています。

今回用意したスクリプトを、誰でもアクセスできる場所に置くと、Trackback SPAM の踏み台にされる可能性もありますので、注意しましょう。

Listings

#!/usr/local/bin/perl -w
# tb_send - Send Trackback Ping

use strict;
use CGI;
use HTTP::Request::Common;
use LWP::UserAgent;

my $query = CGI->new();
   $query->charset('utf-8');

my $mode  = $query->param('mode');
if ($mode && $mode eq 'form') {
    show_ping_form($query);
} else {
    my $v = $query->Vars();
    if ($v->{ping_url} && $v->{title} && $v->{url}) {
        my $message = send_ping($v);
        show_ping_form($query, $message);
    } else {
        show_ping_form($query, "invalid parameters");
    }
}

sub show_ping_form {
    my($query, $message) = @_;
    $message ||= '';
    print $query->header, <<HTML;
<html>
<body>
$message
<form>
Ping URL: <input type="text" name="ping_url" size="30" /><br />
Title:    <input type="text" name="title" size="30" /><br />
Blogname: <input type="text" name="blog_name" size="30" /><br />
Blog URL: <input type="text" name="url" size="30" /><br />
Excerpt:  <input type="text" name="excerpt" size="50" /><br />
<input type="submit" value="Send" />
</form>
</body></html>
HTML
    ;
}

sub send_ping {
    my $v = shift;
    my $ua = LWP::UserAgent->new();
       $ua->agent("tb_send/1.0");
    my $req = POST $v->{ping_url}, [
        title     => $v->{title},
        url       => $v->{url},
        blog_name => $v->{blog_name},
        excerpt   => $v->{excerpt},
        charset   => 'utf-8',
    ];
    my $response = $ua->request($req);
    unless ($response->is_success) {
        return "HTTP error: " . $response->status_line;
    }

    $response->content =~ m!<error>(\d+).*<message>(.+?)</message>!s;
    return $1 ? "Error: $2" : "Ping to $v->{ping_url} successful";
}

*1) Feature: Trackback が、Trackback をはじめて紹介しているエントリと思われます。
*2) もちろん他の Blog ツールでも同様に記事ごとに固有の Trackback URL が用意されていることが多いようです。
*3) 簡易のため正規表現で拾っています。XML::Simple などを使用してもいいですが、これだけシンプルな XML にわざわざパーサをつかうのは、鉛筆をノコギリで削るようなもので、ちょっとオーバースペックな気もします。

Trackback Ping を送信する

サンプルコード

実行例

Hack the Hacks

Listings