Winamp で再生中の曲を Blog に

自分のローカル MP3 プレイヤーで聞いている曲を、Blog のサイドバーに表示させたら楽しいですよね。今回は Winamp の再生中の曲を HTTP で通知し、RSS ファイルを生成してみます。

DoSomething Plugin

ですが、この方法は誰でもできる、というほど簡単なものではありません。今回は、Winamp の DoSomething Plugin というよりジェネリックなプラグインを使用します。このプラグインは、

A Winamp General Purpose Plugin which is geared toward Shoutcasters. Whenever a song changes (or predetermined time interval) this plugin is responsible for doing "something". The somethings that are supported are as follows :

Submit A URL
FTP A file
Generate an HTML Playlist (Just like MusicTicker)
Run a command
Gather XML Statistics (this uses the Shoutcast XML admin interface to gather statistics about your broadcast, you can then use tags to substitute this information into any of the above actions)

今回は、このうち Submit A URL の機能を使用して、

1. Winamp が曲が変わるたびに特定の CGI URL に送信
2. CGI でデータを RSS 化して保存

The Code

our $RssPath    = "now_playing.xml"; # path for RSS data
our $MaxEntries = 15;                # number of items to store
our $ClientEncoding = "Shift_JIS";   # DoSomething songinfo encoding

my $q = CGI->new();
my $song = _param($q, 'song');

sub _param {
    my($q, $name) = @_;
    my $value = $q->param($name);
    return decode($ClientEncoding, $value);
}

my $rss = XML::RSS->new(version => 0.91);

if (-e $RssPath) {
    eval {
        $rss->parsefile($RssPath);
        pop(@{$rss->{items}}) if @{$rss->{items}} >= $MaxEntries;
    };
}

$MaxEntries より数が増えている場合には、最後の1個のエントリを pop で削除しています(*3)。

$rss->channel(
    title => "Now Playing",
    pubDate => time2str(time),
);

$rss->add_item(
    title => $song,
    mode  => "insert",
);

$rss->save($RssPath);

print $q->header, "Thanks, DoSomething!";

Running the Hack

DoSomething Plugin をダウンロードして dosomethingv2_12.exe を実行します。とくにインストール自体は何の設定もなく終了するはずです。

次に DoSomething プラグインのアクションを設定します。Winamp を起動し、Options → Preference で設定画面を開き、Plug-ins → General Purpose から "DoSomething Plugin" を選択します。 "Disable Plugin" のチェックをはずし、"Actions" から "Submit A URL" を選択、URL を

http://example.com/now_playing.cgi?song=%%CURRENTSONG%%

Winamp で適当に曲を再生、また曲を変更してみましょう。プレイヤーの見た目はとくに変化しませんが、now_playing.cgi に対してリクエストが飛ばされているはずです。うまく動作すれば、$RssPath で設定したパスに RSS ファイル now_playing.xml が作成されています。サンプルの now_playing.xml は List 2 のようになります。

ここまでできれば、あとは出力された RSS ファイルを JavaScript 化して、Client Side Include で Blog のサイドバーなどに出力するとよいでしょう。

Hacking the Hack

RSS を使用していますが、それぞれの item に link 要素や description 要素が設定されていません。例えば AmazonWebServices を使用してアソシエイトへのリンクを link に設定したり、レビューを取得して description に設定したり、といったことができるとさらに面白いでしょう。

See Also

• Trackbacks in Winamp
• blosxom: now_playing plugin

Listings

#!/usr/local/bin/perl -w
# now_playing - Save winamp info to RSS

use strict;
use CGI;
use Encode;
use HTTP::Date;
use XML::RSS;

our $RssPath    = "now_playing.xml"; # path for RSS data
our $MaxEntries = 15;                # number of items to store
our $ClientEncoding = "Shift_JIS";   # DoSomething songinfo encoding

my $q = CGI->new();
my $song = _param($q, 'song');

my $rss = XML::RSS->new(version => 0.91);

if (-e $RssPath) {
    eval {
        $rss->parsefile($RssPath);
        pop(@{$rss->{items}}) if @{$rss->{items}} >= $MaxEntries;
    };
}

$rss->channel(
    title => "Now Playing",
    pubDate => time2str(time),
);

$rss->add_item(
    title => $song,
    mode  => "insert",
);

$rss->save($RssPath);

print $q->header, "Thanks, DoSomething!";

sub _param {
    my($q, $name) = @_;
    my $value = $q->param($name);
    return decode($ClientEncoding, $value);
}

<?xml version="1.0" encoding="UTF-8"?>

<!DOCTYPE rss PUBLIC "-//Netscape Communications//DTD RSS 0.91//EN"
            "http://my.netscape.com/publish/formats/rss-0.91.dtd">

<rss version="0.91">

<channel>
<title>Now Playing</title>
<link></link>
<description></description>
<pubDate>Tue, 09 Dec 2003 19:09:54 GMT</pubDate>

<item>
<title> Busted - Air Hostess </title>
<link></link>
</item>

<item>
<title> The Ataris - So long, Astoria </title>
<link></link>
</item>

<item>
<title> Crystal Kay - Can't be Stopped </title>
<link></link>
</item>

</channel>
</rss>

posted at: 05:08 by miyagawa | category: RSS | permalink
Trackback (4) | Printer Friendly | Email this blog