RSS をメールで送信する

RSS は Aggregator で読んだり、自分の Blog に張りつけたりと、様々な使用法がありますが、トラディショナルに、お気に入りの MUA (メーラ) で RSS の更新情報をメールで受信したいという欲求もあるでしょう。今回は、RSS を取得して Email で送信するスクリプトをつくってみます。

RSS のパース

my $rss = XML::RSS->new();
$rss->parse($doc);
$rss->parsefile($file);

DublinCore: メタデータ

関心空間の RSS を作成する では、RSS 0.91 の RSS を作成していたため、出力された RSS を見ただけでは、それぞれのアイテムの更新日付がわかりません。更新情報を取得して差分で何か処理するような場合にはこれでは不便です。そこで RSS 1.0 や RSS 2.0 では、モジュールを使用して、更新時刻などのコアには含まれないメタデータを RSS に含めることができます。

ここでは、名前空間 dc (*1) で定義される DublinCore モジュールを使用します。Dublin Core は、ウェブ上のセマンティックなデータの基礎として定義されたメタデータで、Dublin Core Metadata Initiative により策定されています。Dublin Core には Title や Creator 等、様々なデータがありますが、今回はそのうち日付を表わす Date を使用します。

サンプルコード

use Digest::MD5 qw(md5_hex);
use Encode;
use File::stat;
use HTTP::Date;
use LWP::Simple;
use MIME::Lite;
use XML::RSS;

our $CacheDir = "rsscache";
our $MailTo   = 'you@example.com';

mkdir $CacheDir, 0755 unless -e $CacheDir;

my $rss    = shift or die "Usage: rss2email URL\n";
my $digest = md5_hex($rss);
my $cache  = "$CacheDir/$digest.xml";

my $lastmod = -e $cache ? stat($cache)->mtime : 0;
my $status = LWP::Simple::mirror($rss, $cache);

if ($status == RC_NOT_MODIFIED) {
    warn "$rss not modified\n";
} elsif (is_error($status)) {
    die "$rss not found!\n";
} elsif (is_success($status)) {
    proc_rss($cache, $lastmod);
}

sub proc_rss {
    my($xml, $lastmod) = @_;
    my $rss = XML::RSS->new();
    $rss->parsefile($xml);

    for my $item (@{$rss->{items}}) {
        my $dc_date = $item->{dc}->{date}
            or die "RSS should have dc:date element";
        my $epoch = HTTP::Date::str2time($dc_date);
        if ($epoch > $lastmod) {
            do_sendmail($rss, $item, $epoch);
        } else {
            last;
        }
    }

Dublin Core の date 文字列は、ISO 8601 のサブセットである W3CDTF フォーマット(*2) で表記されているため、これをパースします。今回は HTTP::Date モジュールがうまく処理できるようなので、これを使用していますが、Date::Parse モジュール、また DateTime::Format::W3CDTF でも処理できるようです(*3)。POSIX の strptime などを使用してもパースすることは可能ですが、サイトやツールごとに表記の揺れが激しかったりして大変なので、こうしたモジュールを使用する方がベターでしょう。

パースした結果、もともとのキャッシュファイルの更新時刻 $lastmod より新しいエントリについては、do_sendmail でメールを送信します(*4)。キャッシュの mtime より古いエントリが登場したら、ループを抜けています。これは通常 RSS ファイルのエントリは新着順であるという慣習によっていますが、そうでない場合もありそうですので、last を next にした方がよいかもしれません。

sub do_sendmail {
    my($rss, $item, $epoch) = @_;
    my $body = <<BODY;
New entry arrived for $rss->{channel}->{title}
$item->{link}
>> $item->{description}
BODY
    ;

    my $mime = MIME::Lite->new(
        From => $MailTo,
        To   => $MailTo,
        Subject => encode('MIME-Header' => $item->{title}),
        Type => 'text/plain; charset=UTF-8',
        Encoding => '8bit',
        Data => encode('UTF-8' => $body),
        Datestamp => 0,
        Date => HTTP::Date::time2str($epoch),
    );

またちょっとしたことですが、RSS 内の dc:date で設定してある日付が、メールの Date: ヘッダにつくよう、Datestamp と Date も設定してあります。

    $mime->send();

実行例

% ./rss2email.pl http://blog.bulknews.net/cookbook/blosxom/index.rss10

See Also

• HAIL 2 U! の kyo 氏による RSS Headline Mailer も同様に、RSS を取得して メールを送信するスクリプトです。複数の RSS URL などにも対応しています。

Listings

#!/usr/local/bin/perl -w
# rss2email - send email from RSS feed

use strict;
use Digest::MD5 qw(md5_hex);
use Encode;
use File::stat;
use HTTP::Date;
use LWP::Simple;
use MIME::Lite;
use XML::RSS;

our $CacheDir = "rsscache";
our $MailTo   = 'you@example.com';

mkdir $CacheDir, 0755 unless -e $CacheDir;

my $rss    = shift or die "Usage: rss2email URL\n";
my $digest = md5_hex($rss);
my $cache  = "$CacheDir/$digest.xml";

my $lastmod = -e $cache ? stat($cache)->mtime : 0;
my $status = LWP::Simple::mirror($rss, $cache);

if ($status == RC_NOT_MODIFIED) {
    warn "$rss not modified\n";
} elsif (is_error($status)) {
    die "$rss not found!\n";
} elsif (is_success($status)) {
    proc_rss($cache, $lastmod);
}

sub proc_rss {
    my($xml, $lastmod) = @_;
    my $rss = XML::RSS->new();
    $rss->parsefile($xml);

    for my $item (@{$rss->{items}}) {
        my $dc_date = $item->{dc}->{date}
            or die "RSS should have dc:date element";
        my $epoch = HTTP::Date::str2time($dc_date);
        if ($epoch > $lastmod) {
            do_sendmail($rss, $item, $epoch);
        } else {
            last;
        }
    }
}

sub do_sendmail {
    my($rss, $item, $epoch) = @_;
    my $body = <<BODY;
New entry arrived for $rss->{channel}->{title}
$item->{link}
>> $item->{description}
BODY
    ;
    my $mime = MIME::Lite->new(
        From => $MailTo,
        To   => $MailTo,
        Subject => encode('MIME-Header' => $item->{title}),
        Type => 'text/plain; charset=UTF-8',
        Encoding => '8bit',
        Data => encode('UTF-8' => $body),
        Datestamp => 0,
        Date => HTTP::Date::time2str($epoch),
    );
    $mime->send();
}

posted at: 22:29 by miyagawa | category: RSS | permalink
Trackback (4) | Printer Friendly | Email this blog